Access交流网
  • 设为首页|收藏本站|繁体中文|手机版
  •     
  • Access培训-Access开发平台-Access行业开发

  • 首页
  • 资讯
  • 技巧
  • 源码
  • 行业
  • 资源
  • 活动
  • 关于

技巧

ACCESS数据库

启动/设置/选项/背景

修复/压缩

安全/加密/解密

快捷键

版本升级/其它等

数据表

命名方式/设计规范

表设计

查询

Sql语言基础

选择查询

更新查询

删除查询

追加查询

生成表查询

交叉表查询

SQL特定查询

查询参数

查询综合应用

界面/窗体/控件

标签

文本框

命令按钮

组合框/列表框

选项组/复选框/选项按钮

选项卡

子窗体

窗体本身/综合应用

其它

报表打印

报表设计

高级报表

模块/函数/VBA/API/系统

VBA基础

内置函数

调试/跟踪/Debug

模块/类模块

API/COM/系统相关

字符数字日期

网络通信游戏

加密解密安全

文件处理

经典算法

宏/菜单/工具栏/功能区

宏/脚本

菜单/工具栏

功能区/Ribbon

图表/图形/图像/多媒体

图表

图形/图像

音频

视频/动画

DAO/链接表/ADO/ADP

DAO/链接表/ODBC

ADO/RDO

ADP

ActiveX/第三方控件/插件

Treeview树控件

ListView列表控件

Toolbar工具栏控件

微软其它控件

Dbi-Tech

CodeJock

Grid++Report

FastReport

ComponentOne

加载项/插件/Addin

OFFICE集成/导入导出/交互

Excel导入导出/交互

Word导入导出/交互

PPT交互

Outlook控制/邮件

Text文本文件/INI/CSV

PDF/SWF/XML格式

CAD格式

Sharepoint/其它Office

SqlServer/其它数据库

表

视图

存储过程/触发器

函数

用户/权限/安全

调试/维护

SqlServer其它/综合

发布/打包/文档/帮助

开发版/运行时

打包/发布/部署

开发文档/帮助制作

Access完整行业系统

采购管理系统

销售管理系统

仓库管理系统

人力资源管理HRM

CRM管理系统

MRP/ERP管理系统

BRP/流程优化

其它管理系统

心得/经验/绝招
其它/杂项
Excel技巧

Excel应用与操作

Excel开发编程

Word技巧

Word应用与操作

Word开发编程

Outlook技巧

Outlook应用与操作

Outlook开发编程

热门文章

  • VBA语句集400句(一部..
  • Access函数判断每月最..
  • Access如何将二进制U..
  • RecordSource ..
  • 代码导出导入自定义菜单示例
  • 如何用VBA更改数据库密码

最新文章

  • Access或VB VBA..
  • 关于VBA的0、""(空字..
  • Access导出函数Out..
  • Access日期与日期区间..
  • RecordSource ..
  • Access子窗体事件控制..

联系方式

Access交流网(免费Access交流)

QQ:18449932 

网  址:www.access-cn.com

当前位置:首页 > 技巧 > 模块/函数/VBA/API/系统 > VBA基础
VBA基础

Access2007功能区开发-modRibbonPublic模块

正 文:

Option Compare Database
Option Explicit
'----------------------------------------------------------
'modRibbonPublic模块 : 与Ribbon类配合使用
'相关 : clsRibbon类/clsRibbonControl类/modRibbonPrivate模块
'       modOGL2007模块
'日期 : 2009.05.02
'作者 : 朱亦文
'目的 : 获取功能区名称
'       功能区加载设置
'       加载功能区控件的图片
'       默认获取属性的方法
'----------------------------------------------------------
Public Ribbons      As New Collection   ' 全局功能区对象集合
Public ImagePath    As String           ' 默认功能区控件图片路径
'----------------------------------------------------------
'函数 : ActiveFormRibbonName
'日期 : 2009.05.02
'作者 : 朱亦文
'目的 : 获取当前活动窗体的功能区名称
'
'       用于 onRibbonLoad 得到功能区的名称
'----------------------------------------------------------
Public Function ActiveFormRibbonName() As String
    On Error Resume Next
    ActiveFormRibbonName = Screen.ActiveForm.ribbonName
End Function

'----------------------------------------------------------
'函数 : ActiveReportName
'日期 : 2009.05.02
'作者 : 朱亦文
'目的 : 获取当前活动报表的功能区名称
'
'       用于 onRibbonLoad 得到功能区的名称
'----------------------------------------------------------
Public Function ActiveReportRibbonName() As String
    On Error Resume Next
    ActiveReportRibbonName = Screen.ActiveReport.ribbonName
End Function
'----------------------------------------------------------
'函数 : ProjectRibbonName
'日期 : 2009.05.02
'作者 : 朱亦文
'目的 : 获取当前项目的功能区名称
'
'       用于 onRibbonLoad 得到功能区的名称
'----------------------------------------------------------
Public Function ProjectRibbonName() As String
'    Dim Obj As Object
'    Const conPropNotFoundError = 3270
'    Dim dbs As DAO.Database
'
'    On Error GoTo ErrProjectRibbonName
'    Set dbs = CurrentDb
    ProjectRibbonName = CurrentProject.Properties!CustomRibbonID
    Exit Function
   
ErrProjectRibbonName:
    Resume Next
End Function
'----------------------------------------------------------
'过程 : onRibbonLoad
'日期 : 2009.05.02
'作者 : 朱亦文
'目的 : 加载功能区的回调
'
'       作用于 :
'       <customUI xmlns="http://schemas.microsoft.com/office/2006/01/customui" OnLoad = "onRibbonLoad">
'----------------------------------------------------------
Public Sub onRibbonLoad(Ribbon As IRibbonUI)
    On Error GoTo err_onRibbonLoad
   
    Dim ribbonName As String
   
    ' 以当前活动的窗体、报表的功能名称作为功能区的名称
    ribbonName = ActiveFormRibbonName() & ActiveReportRibbonName()
   
    '默认全局功能区的名称
    If ribbonName = "" Then ribbonName = ProjectRibbonName
   
    Dim myRibbon As New clsRibbon   '新建功能区对象
    myRibbon.Name = ribbonName      '设置名称
    Set myRibbon.Ribbon = Ribbon    '设置对象引用的功能区
   
    Ribbons.Add myRibbon, ribbonName
    On Error GoTo 0
    Exit Sub
   
err_onRibbonLoad:
    Debug.Print Err.Number, Err.Description, "onRibbonLoad", Err.Source
    Resume Next
End Sub

'----------------------------------------------------------
'过程 : LoadImages
'日期 : 2009.05.02
'作者 : 朱亦文
'目的 : 加载功能区时加载控件的图片
'
'       作用于 :
'       <customUI xmlns="http://schemas.microsoft.com/office/2006/01/customui" loadImage = "LoadImages">
'           加载
'           <button id="btnMessage" label="最新消息" size="large" image="message.png" onAction="onButtonClick" />
'           image 属性所指定的图片
'
'       strImage : image 属性值
'       Image    : StdPicture, 返回值
'----------------------------------------------------------
Public Sub LoadImages(strImage As String, ByRef image)
    '<button id="btnMessage" label="最新消息" size="large" image="message.png" onAction="onButtonClick" />
   
    If strImage <> "" Then
        If LCase(Left(strImage, 4)) = "mso." Then
            image = Mid(strImage, 5)
        Else
            Dim sImgPath As String
            If ImagePath = "" Then ImagePath = CurrentProject.Path & "\Pics"
            sImgPath = ImagePath & "\" & strImage
           
            Set image = LoadPictureGDIP(sImgPath)
        End If
    End If
   
End Sub

'----------------------------------------------------------
'过程 : GetVisible
'日期 : 2009.05.02
'作者 : 朱亦文
'目的 : 设置功能区控件的可见性,由于功能区的回调函数中没有
'       功能区的名称,只能在功能区的回调函数中直接指定调用
'       的功能区的名称,从而才能从功能区控件集合中获得值。
'
'       作用于 :
'       功能区getVisible回调
'       <labelControl id="labUnit" getVisible="Main_GetVisible" />
'       modRibbonPrivate模块
'       Public Sub Main_GetVisible(control As IRibbonControl, ByRef visible As Variant)
'           Call GetVisible("Main", control, visible)
'       End Sub
'----------------------------------------------------------
Public Sub GetVisible(ribbonName As String, control As IRibbonControl, ByRef Visible As Variant)
    On Error GoTo ErrGetVisible
   
    Visible = True
    Visible = Ribbons(ribbonName).Controls(control.id).Visible
   
    On Error GoTo 0
    Exit Sub
ErrGetVisible:
    Debug.Print Err.Number, Err.Description
    Resume Next
End Sub

'----------------------------------------------------------
'过程 : GetEnable
'日期 : 2009.05.02
'作者 : 朱亦文
'目的 : 设置功能区控件的可用性
'
'       作用于 :
'       功能区getEnable回调
'       <button id="btnMessage" label="最新消息" size="large" image="message.png" getEnable="Main_GetEnable" onAction="onButtonClick" />
'       modRibbonPrivate模块
'       Public Sub Main_GetEnable(control As IRibbonControl, ByRef enabled As Variant)
'           Call GetEnable("Main", control, enabled)
'       End Sub
'----------------------------------------------------------
Public Sub GetEnable(ribbonName As String, control As IRibbonControl, ByRef Enabled As Variant)
    On Error GoTo ErrGetEnabled
   
    Enabled = True
    Enabled = Ribbons(ribbonName).Controls(control.id).Enabled
   
    On Error GoTo 0
    Exit Sub
ErrGetEnabled:
    Debug.Print Err.Number, Err.Description
    Resume Next
End Sub

'----------------------------------------------------------
'过程 : GetLabel
'日期 : 2009.05.02
'作者 : 朱亦文
'目的 : 设置功能区控件的标题
'
'       作用于 :
'       功能区getLabel回调
'       <button id="btnMessage" size="large" image="message.png" getLabel="Main_GetLabel" />
'       modRibbonPrivate模块
'       Public Sub Main_GetEnable(control As IRibbonControl, ByRef label As Variant)
'           Call GetEnable("Main", control, label)
'       End Sub
'----------------------------------------------------------
Public Sub GetLabel(ribbonName As String, control As IRibbonControl, ByRef Label As Variant)
    On Error GoTo ErrGetLabel
   
    Label = ""
   
    Dim lab As String
    lab = Ribbons(ribbonName).Controls(control.id).Label
   
'    If lab = "" Then
'        Select Case control.id
'        Case "labUnit": lab = "单位:" & PJ.UserUnit
'        Case "labUser": lab = "用户:" & PJ.UserNick
'        Case "labDate": lab = "今天是" & FormatDateTime(Date, vbLongDate)
'        End Select
'    End If
   
    Label = lab
   
    On Error GoTo 0
    Exit Sub
ErrGetLabel:
    Debug.Print Err.Number, Err.Description
    Resume Next
End Sub

'----------------------------------------------------------
'过程 : GetImage
'日期 : 2009.05.02
'作者 : 朱亦文
'目的 : 设置功能区控件的图片
'
'       作用于 :
'       功能区getImage回调
'       <button id="btnMessage" size="large" getImage="Main_GetImage" tag="mso.HappyFace" />
'           其中tag指定控件的默认图片
'       modRibbonPrivate模块
'       Public Sub Main_GetImage(control As IRibbonControl, ByRef image)
'           Call GetImage("Main", control, image)
'       End Sub
'----------------------------------------------------------
Public Sub GetImage(ribbonName As String, control As IRibbonControl, ByRef image)
    On Error GoTo ErrGetImage
   
    Dim sImgName As String  ' 图片文件名或Office图片名称
   
    If Ribbons(ribbonName).Controls(control.id).image = "" Then
        sImgName = control.tag
    Else
        sImgName = Ribbons(ribbonName).Controls(control.id).image
    End If
   
    If sImgName <> "" Then
        If LCase(Left(sImgName, 4)) = "mso." Then
            image = Mid(sImgName, 5)
        Else
            Dim sImgPath As String
            If ImagePath = "" Then ImagePath = CurrentProject.Path & "\Pics"
            sImgPath = ImagePath & "\" & sImgName
           
            Set image = LoadPictureGDIP(sImgPath)
        End If
    End If
   
    On Error GoTo 0
    Exit Sub
ErrGetImage:
    Debug.Print Err.Number, Err.Description
    Resume Next
End Sub

发布人:朱亦文-网络  
分享到:
点击次数:  更新时间:2009-09-09 09:34:43  【打印此页】  【关闭】
上一条:在Access中手动拆分数据库  下一条:从Access中启动MSBackup.exe



相关文章

  • • Access或VB VBA判断数组的值是否为空的几种方法
  • • 关于VBA的0、""(空字符串)、Null、Empty、与 Nothing 的区别
  • • Access导出函数OutPutto解释
  • • Access日期与日期区间的筛选
  • • RecordSource SourceObject ControlSource属性的区别
  • • Access子窗体事件控制父窗体
  • • 事件​change和AfterUpdate的区别
  • • 代码修改完善方法示例(初学者必读)

热门文章

  • [2009-04-11] 动态引用 DLL 库access数据库
  • [2005-08-16] 初识VBA:第四课 计算器代码的编写access数据库
  • [2004-11-23] 将金额数字转换汉字大写access数据库
  • [2005-02-06] 一个常用的组合多条件查询 WHERE 子句的函数access数据库
  • [2013-11-02] vba条件语句的两种表示方法access数据库
  • [2008-12-06] Access計算工作天數access数据库

热门产品

公司动态|在线留言|在线反馈|友情链接|会员中心|站内搜索|网站地图

Access交流网 版权所有 1999-2018 粤ICP备10043721号

QQ:18449932

Access应用 Access培训 Access开发 Access平台

access|数据库|access下载|access教程|access视频|access软件

Powered by MetInfo 5.3.12 ©2008-2023  www.metinfo.cn